switch(MIDI.getType()) - working only first process

[elektronek]

Hello,
i'm use current version midi library 5.0.2, but this situation also occurred with the older version

if i'm use processing with getType(), working only first case with noteOn, second ControlChange not working. If exchange it, first CC and second NoteOn, working only CC case. With handle processing, without getType() working all fine.

switch(MIDI.getType())
{ 
  case midi::NoteOn:  // this working OK
    uint8_t note = MIDI.getData1();
    if (note==33||note==35||note==36) kickstate = 1;  
    break;

  case midi::ControlChange:   // not working
    digitalWrite(13, HIGH); // for indication, defined in setup as output, not used elsewhere
    uint8_t cc  = MIDI.getData1();
    uint8_t val = MIDI.getData2();
    if (cc==102 && val > 0 && val < 17) count=val;
    if (cc==103 && val > 0 && val < 9)  scene=val-1;
    break;

  default:
    break;
}

Arduino IDE 1.8.9, Atmega328P without bootloader in my own board programmed via usbasp

Best Regards!
Martin

[franky47]

Can I see the rest of your code please?

MIDI.getType only returns the type of the last message received, so depending on where and when you call it, it may behave differently.

I would generally suggest to use callbacks to perform this kind of "if this type of message arrived, then do this" switching.

In your case:

void handleNoteOn(byte channel, byte note, byte velocity) {
  if (note==33||note==35||note==36) kickstate = 1;
}
void handleControlChange(byte channel, byte number, byte value) {
  digitalWrite(13, HIGH); // for indication, defined in setup as output, not used elsewhere
  if (number==102 && value > 0 && value < 17) count=value;
  if (number==103 && value > 0 && value < 9)  scene=value-1;
}

void setup() {
  MIDI.begin();
  MIDI.setHandleNoteOn(handleNoteOn);
  MIDI.setHandleControlChange(handleControlChange);
}

void loop() {
  MIDI.read();
}

[franky47]

Ah sorry I missed it on the first glance, but since you are assigning variables in each case, you'll have to surround them with curly braces, it's one of those weird C/C++ things I always forget (and why I usually avoid switch/case):

switch(MIDI.getType())
{ 
  case midi::NoteOn: {
    // this working OK
    uint8_t note = MIDI.getData1();
    if (note==33||note==35||note==36) kickstate = 1;  
  }
  break;

  case midi::ControlChange:  { 
   // not working
    digitalWrite(13, HIGH); // for indication, defined in setup as output, not used elsewhere
    uint8_t cc  = MIDI.getData1();
    uint8_t val = MIDI.getData2();
    if (cc==102 && val > 0 && val < 17) count=val;
    if (cc==103 && val > 0 && val < 9)  scene=val-1;
  }
  break;

  default:
    break;
}

[elektronek]

Hello Franky47,
Great! Thank you very much!
I forgot such a trifle and it solved the whole problem
Now working correctly :-)

Best Regards!
Martin

[elektronek]

Btw for function MIDI.check()

first call check() and if be returned 1 next call read() ?

[franky47]

Ah, no, and that could actually be your problem: check will verify that things returned by MIDI.getType, getData1 etc are valid. But those are populated when receiving messages via MIDI.read, so it should be the other way around:

MIDI.read();
if (MIDI.check()) {
  switch (MIDI.getType()) {
    // ...
  }
}

In practice though, check is not needed here: MIDI.read will return true when it has received a message, so you can do what you did before:

if (MIDI.read())
{
  switch(MIDI.getType()) {
    // ...
  }
}

[elektronek]

Hello Franky47,
thank you very much for your help :-)

Best Regards!
Martin