diff --git a/examples/adafruitio_led_SSL_esp8266/.zero.test.skip b/examples/adafruitio_led_SSL_esp8266/.zero.test.skip
new file mode 100644
index 0000000..8b13789
--- /dev/null
+++ b/examples/adafruitio_led_SSL_esp8266/.zero.test.skip
@@ -0,0 +1 @@
+
diff --git a/examples/adafruitio_led_SSL_esp8266/adafruitio_led_SSL_esp8266.ino b/examples/adafruitio_led_SSL_esp8266/adafruitio_led_SSL_esp8266.ino
new file mode 100644
index 0000000..8b8620f
--- /dev/null
+++ b/examples/adafruitio_led_SSL_esp8266/adafruitio_led_SSL_esp8266.ino
@@ -0,0 +1,168 @@
+/***************************************************
+  Adafruit_led_SSL_esp8266 Example
+
+  Must use ESP8266 Arduino from:
+    https://github.com/esp8266/Arduino
+
+  Works great with Adafruit's Huzzah ESP board & Feather
+  ----> https://www.adafruit.com/product/2471
+  ----> https://www.adafruit.com/products/2821
+
+  Adafruit invests time and resources providing this open source code,
+  please support Adafruit and open-source hardware by purchasing
+  products from Adafruit!
+
+  Written by aandroide (GitHub)
+  MIT license, all text above must be included in any redistribution
+ ****************************************************/
+#include <ESP8266WiFi.h>
+#include "Adafruit_MQTT.h"
+#include "Adafruit_MQTT_Client.h"
+
+// the on off button feed turns this LED on/off
+#define LED 13
+
+/************************* WiFi Access Point *********************************/
+
+#define WLAN_SSID       "...your SSID..."
+#define WLAN_PASS       "...your password..."
+
+/************************* Adafruit.io Setup *********************************/
+
+#define AIO_SERVER      "io.adafruit.com"
+#define AIO_SERVERPORT  8883                   // 8883 for MQTTS
+#define AIO_USERNAME    "...your AIO username (see https://accounts.adafruit.com)..."
+#define AIO_KEY         "...your AIO key..."
+
+/************ Global State (you don't need to change this!) ******************/
+
+// WiFiFlientSecure for SSL/TLS support
+WiFiClientSecure client;
+
+// Setup the MQTT client class by passing in the WiFi client and MQTT server and login details.
+Adafruit_MQTT_Client mqtt(&client, AIO_SERVER, AIO_SERVERPORT, AIO_USERNAME, AIO_USERNAME, AIO_KEY);
+
+/****************************** Feeds ***************************************/
+
+// Notice MQTT paths for AIO follow the form: <username>/feeds/<feedname>
+Adafruit_MQTT_Subscribe onoffbutton = Adafruit_MQTT_Subscribe(&mqtt, AIO_USERNAME "/feeds/onoff");
+
+// io.adafruit.com SHA1 fingerprint
+const char* fingerprint = "77 00 54 2D DA E7 D8 03 27 31 23 99 EB 27 DB CB A5 4C 57 18";
+
+/*************************** Sketch Code ************************************/
+
+// Bug workaround for Arduino 1.6.6, it seems to need a function declaration
+// for some reason (only affects ESP8266, likely an arduino-builder bug).
+void MQTT_connect();
+void verifyFingerprint();
+
+void setup() {
+  pinMode(LED, OUTPUT);
+  digitalWrite(LED, LOW);
+  
+  Serial.begin(115200);
+  delay(10);
+
+  Serial.println(F("Adafruit IO MQTTS (SSL/TLS) Example"));
+
+  // Connect to WiFi access point.
+  Serial.println(); Serial.println();
+  Serial.print("Connecting to ");
+  Serial.println(WLAN_SSID);
+
+  WiFi.begin(WLAN_SSID, WLAN_PASS);
+  while (WiFi.status() != WL_CONNECTED) {
+    delay(500);
+    Serial.print(".");
+  }
+  Serial.println();
+
+  Serial.println("WiFi connected");
+  Serial.println("IP address: "); Serial.println(WiFi.localIP());
+  
+  // Setup MQTT subscription for onoff & slider feed.
+  mqtt.subscribe(&onoffbutton);
+  // check the fingerprint of io.adafruit.com's SSL cert
+  verifyFingerprint();
+ }
+
+void loop() {
+  // Ensure the connection to the MQTT server is alive (this will make the first
+  // connection and automatically reconnect when disconnected).  See the MQTT_connect
+  // function definition further below.
+  MQTT_connect();
+
+  // this is our 'wait for incoming subscription packets' busy subloop
+  // try to spend your time here
+
+  Adafruit_MQTT_Subscribe *subscription;
+  while ((subscription = mqtt.readSubscription(5000))) {
+    // Check if its the onoff button feed
+    if (subscription == &onoffbutton) {
+      Serial.print(F("Button: "));
+      Serial.println((char *)onoffbutton.lastread);
+      
+      if (strcmp((char *)onoffbutton.lastread, "ON") == 0) {
+        digitalWrite(LED, HIGH); 
+      }
+      if (strcmp((char *)onoffbutton.lastread, "OFF") == 0) {
+        digitalWrite(LED, LOW); 
+      }
+    }
+   }
+
+  // ping the server to keep the mqtt connection alive
+  if(! mqtt.ping()) {
+    mqtt.disconnect();
+  }
+
+}
+
+void verifyFingerprint() {
+
+  const char* host = AIO_SERVER;
+
+  Serial.print("Connecting to ");
+  Serial.println(host);
+
+  if (! client.connect(host, AIO_SERVERPORT)) {
+    Serial.println("Connection failed. Halting execution.");
+    while(1);
+  }
+
+  if (client.verify(fingerprint, host)) {
+    Serial.println("Connection secure.");
+  } else {
+    Serial.println("Connection insecure! Halting execution.");
+    while(1);
+  }
+
+}
+
+// Function to connect and reconnect as necessary to the MQTT server.
+// Should be called in the loop function and it will take care if connecting.
+void MQTT_connect() {
+  int8_t ret;
+
+  // Stop if already connected.
+  if (mqtt.connected()) {
+    return;
+  }
+
+  Serial.print("Connecting to MQTT... ");
+
+  uint8_t retries = 3;
+  while ((ret = mqtt.connect()) != 0) { // connect will return 0 for connected
+       Serial.println(mqtt.connectErrorString(ret));
+       Serial.println("Retrying MQTT connection in 5 seconds...");
+       mqtt.disconnect();
+       delay(5000);  // wait 5 seconds
+       retries--;
+       if (retries == 0) {
+         // basically die and wait for WDT to reset me
+         while (1);
+       }
+  }
+  Serial.println("MQTT Connected!");
+}