build.gradle

plugins {
    id 'application'
    id 'org.openjfx.javafxplugin' version '0.0.13'  //requires JDK11+
    id 'org.beryx.jlink' version '2.25.0'
}

wrapper {
    gradleVersion = '7.4.2'
    distributionType = Wrapper.DistributionType.ALL
}

group = 'com.javafx.experiments'
version = '1.0.0-SNAPSHOT'

ext {
    mainModuleName = 'Viewer3D'
    mainClassName = 'com.javafx.experiments.jfx3dviewer.Jfx3dViewerApp'
    launcherClassName = 'com.javafx.experiments.jfx3dviewer.Launcher'
    javafxVersion = '17.0.2'  //requires JDK11+
}

repositories {
    mavenCentral()
    mavenLocal()
}

compileJava {
    options.release = 11  //use JDK11+ for compiling & running
    options.encoding = 'UTF-8'
}

javafx {
    version = javafxVersion
    modules = ['javafx.controls', 'javafx.fxml', 'javafx.swing']
}

jar {
    manifest {
        attributes(
            'Main-Class': project.mainClassName,
            'JavaFX-Version': javafxVersion,
            'Created-By': System.getProperty('java.runtime.version') + ' (' + System.getProperty('java.vendor') + ')',
            'Gradle-Version': 'Gradle ' + gradle.getGradleVersion(),
        )
    }
}

application {
    mainModule = project.mainModuleName
    mainClass = project.mainClassName
    executableDir = ''
}

//main distribution generated would be platform-specific to the current OS
//hence the distribution's name should reflect that
distributions.main.distributionBaseName = project.name + '-' + javafx.platform.classifier

run {
    //args '...'

    //get system properties specified from the command line (for debugging, etc.)
    //and pass them on to the running application's JVM
    systemProperties = System.getProperties()

    debugOptions {
        enabled = false
        port = 5566
        server = true
        suspend = false
    }
}

//make an executable uber jar including all dependencies
//which should work only for current OS platform
task uberJar(type: Jar) {
    archiveClassifier = 'no-deps-' + javafx.platform.classifier
    with jar
    manifest {
        attributes(
            'Main-Class': project.launcherClassName,
            'JavaFX-Version': javafxVersion,
            'Created-By': System.getProperty('java.runtime.version') + ' (' + System.getProperty('java.vendor') + ')',
            'Gradle-Version': 'Gradle ' + gradle.getGradleVersion(),
        )
    }
    from {
        configurations.runtimeClasspath.collect { it.isDirectory() ? it : zipTree(it) }
    }
    duplicatesStrategy 'exclude'
}

jlink {
    options = ['--strip-debug', '--compress', '2', '--no-header-files', '--no-man-pages']
    launcher {
        name = project.mainModuleName
    }
}