feat: terragrunt example with documentation (#165)

* feat: `terragrunt` example + docs

* fix: wrong ref, wrong format

* fix: you can't use "stable"; needs major.minor.patch

* test: tested https link; works as expected; switching link prior to merge

* chore: forgot to remove todo

* chore: remove todo for comments

I think I would rather force people to go read the terragrunt documentation to understand the example.

* fix: forgot to change branch name to `main`

---------

Co-authored-by: Scott Murray <scott@murray.kiwi>

Author: caerulescens

docs/guides/terragrunt.md

@@ -0,0 +1,53 @@
+---
+page_title: "terragrunt Guide - terraform-provider-minikube"
+subcategory: ""
+description: |-
+  Guide for creating minikube cluster with terragrunt
+---
+
+# Guide: Launching `minikube` clusters with `terragrunt`
+
+`terragrunt` is a tool that wraps `terraform` or `tofu` for reusing modules and generating sources.
+This is primarily useful if you're working with a large number of `minikube` configurations, or you're wanting to keep them DRY.
+
+## Prerequisites
+
+* Install [terraform](https://github.com/hashicorp/terraform) or [tofu](https://github.com/opentofu/opentofu)
+* Install [terragrunt](https://github.com/gruntwork-io/terragrunt)
+
+## Terragrunt Project with Common Environment
+
+While it's possible to create a working `terragrunt` project with fewer files, this example is the most generally applicable.
+The [`examples/terragrunt`](https://github.com/scott-the-programmer/terraform-provider-minikube/tree/main/examples) folder contains two projects: `terraform_project` and `terragrunt_project`.
+
+### terraform_project
+
+The `terraform_project` folder is a valid project and can be initialized using the standard `terraform init`, `terraform plan`, and `terraform apply`.
+
+```shell
+cat <<EOF > terraform.tfvars
+cluster_name = "minikube"
+driver       = "docker"
+nodes        = 1
+cpus         = 2
+memory       = 2048
+EOF
+terraform init
+terraform plan
+terraform apply
+```
+
+### terragrunt_project
+
+Within `terragrunt_project/dev`, there are two runnable configurations named `cluster-a` and `cluster-b` that reuse the `terraform_project` with shared inputs; they're run from their working directories using `terragrunt init`, `terragrunt plan`, and `terragrunt apply`.
+
+```shell
+cat <<EOF > terraform.tfvars
+nodes  = 1
+cpus   = 2
+memory = 2048
+EOF
+terragrunt init
+terragrunt plan
+terragrunt apply
+```

examples/guides/terragrunt/terraform_project/backend.tf

@@ -0,0 +1,5 @@
+terraform {
+  backend "local" {
+    path = "terraform.tfstate"
+  }
+}

examples/guides/terragrunt/terraform_project/main.tf

@@ -0,0 +1,23 @@
+terraform {
+  required_providers {
+    minikube = {
+      source  = "scott-the-programmer/minikube"
+      version = "0.3.10"
+    }
+  }
+}
+
+resource "minikube_cluster" "default" {
+  cluster_name        = var.cluster_name
+  driver              = var.driver
+  nodes               = var.nodes
+  cpus                = var.cpus
+  preload             = true
+  cache_images        = true
+  auto_update_drivers = true
+  install_addons      = true
+  addons = [
+    "default-storageclass",
+    "storage-provisioner"
+  ]
+}

examples/guides/terragrunt/terraform_project/outputs.tf

@@ -0,0 +1,27 @@
+output "client_certificate" {
+  value       = minikube_cluster.default.client_certificate
+  description = "The cluster client certificate."
+  sensitive   = true
+}
+
+output "client_key" {
+  value       = minikube_cluster.default.client_key
+  description = "The cluster client key."
+  sensitive   = true
+}
+
+output "cluster_ca_certificate" {
+  value       = minikube_cluster.default.cluster_ca_certificate
+  description = "The cluster CA certificate."
+  sensitive   = true
+}
+
+output "host" {
+  value       = minikube_cluster.default.host
+  description = "The cluster host."
+}
+
+output "id" {
+  value       = minikube_cluster.default.id
+  description = "The cluster id."
+}

examples/guides/terragrunt/terraform_project/provider.tf

@@ -0,0 +1 @@
+provider "minikube" {}

examples/guides/terragrunt/terraform_project/variables.tf

@@ -0,0 +1,24 @@
+variable "cluster_name" {
+  type        = string
+  description = "The minikube name."
+}
+
+variable "driver" {
+  type        = string
+  description = "The minikube driver."
+}
+
+variable "nodes" {
+  type        = number
+  description = "The number of nodes."
+}
+
+variable "cpus" {
+  type        = number
+  description = "The number of cpus."
+}
+
+variable "memory" {
+  type        = number
+  description = "The amount of memory."
+}

examples/guides/terragrunt/terragrunt_project/_envcommon/minikube.hcl

@@ -0,0 +1,28 @@
+locals {
+  base_source_url    = "git::https://github.com/scott-the-programmer/terraform-provider-minikube.git//examples/guides/terragrunt/terraform_project"
+  ref                = "main"
+  kubernetes_version = "v1.28.3"
+}
+
+generate "provider" {
+  path      = "provider.tf"
+  if_exists = "overwrite"
+  contents  = <<EOF
+provider "minikube" {
+  kubernetes_version = "${local.kubernetes_version}"
+}
+EOF
+}
+
+remote_state {
+  backend = "local"
+  generate = {
+    path      = "backend.tf"
+    if_exists = "overwrite"
+  }
+  config = {
+    path = "${get_parent_terragrunt_dir()}/${path_relative_to_include()}/terraform.tfstate"
+  }
+}
+
+inputs = {}

examples/guides/terragrunt/terragrunt_project/dev/cluster-a/terragrunt.hcl

@@ -0,0 +1,16 @@
+include "root" {
+  path = find_in_parent_folders()
+}
+
+include "envcommon" {
+  path   = "${dirname(find_in_parent_folders())}/_envcommon/minikube.hcl"
+  expose = true
+}
+
+terraform {
+  source = "${include.envcommon.locals.base_source_url}?ref=${include.envcommon.locals.ref}"
+}
+
+inputs = {
+  cluster_name = "dev-cluster-a"
+}

examples/guides/terragrunt/terragrunt_project/dev/cluster-b/terragrunt.hcl

@@ -0,0 +1,16 @@
+include "root" {
+  path = find_in_parent_folders()
+}
+
+include "envcommon" {
+  path   = "${dirname(find_in_parent_folders())}/_envcommon/minikube.hcl"
+  expose = true
+}
+
+terraform {
+  source = "${include.envcommon.locals.base_source_url}?ref=${include.envcommon.locals.ref}"
+}
+
+inputs = {
+  cluster_name = "dev-cluster-b"
+}

examples/guides/terragrunt/terragrunt_project/dev/environment.hcl

@@ -0,0 +1,4 @@
+locals {
+  environment = "dev"
+  driver = "docker"
+}

examples/guides/terragrunt/terragrunt_project/terragrunt.hcl

@@ -0,0 +1,9 @@
+locals {
+  # load variables
+  environment_vars  = read_terragrunt_config(find_in_parent_folders("environment.hcl"))
+}
+
+# merge variables
+inputs = merge(
+  local.environment_vars.locals,
+)