feat: initial cpp2b idea

Author: zaucy

.gitignore

@@ -0,0 +1,7 @@
+/.cache
+/dist
+/src/*.cpp
+*.obj
+*.o
+*.exe
+*.a

build.cmd

@@ -0,0 +1,75 @@
+@echo off
+
+set cppfront=%~dp0.cache\tools\cppfront.exe
+set cppfront_include_dir=%~dp0.cache\repos\cppfront\include
+set cpp2b_dist=%~dp0dist\debug\cpp2b
+set modules_dir=%~dp0.cache\modules
+
+if not exist .cache\repos ( mkdir .cache\repos )
+if not exist %modules_dir% ( mkdir %modules_dir% )
+if not exist .cache\tools ( mkdir .cache\tools )
+if not exist dist ( mkdir dist )
+if not exist dist\debug ( mkdir dist\debug )
+
+set vswhere="%ProgramFiles(x86)%\Microsoft Visual Studio\Installer\vswhere.exe"
+
+for /f "usebackq tokens=*" %%i in (`vswhere -latest -products * -requires Microsoft.VisualStudio.Component.VC.Tools.x86.x64 -property installationPath`) do (
+	set vs_install_dir=%%i
+)
+
+if exist "%vs_install_dir%\VC\Auxiliary\Build\Microsoft.VCToolsVersion.default.txt" (
+	set /p vs_tools_version=<"%vs_install_dir%\VC\Auxiliary\Build\Microsoft.VCToolsVersion.default.txt"
+)
+
+if "%vs_tools_version%"=="" (
+	echo Cannot find VC tools installed on your system
+	exit 1
+)
+
+set vs_tools_dir=%vs_install_dir%\VC\Tools\MSVC\%vs_tools_version%
+
+if exist .cache\repos\cppfront\ (
+	@rem TODO - report which cppfront version is being used
+) else (
+	git clone https://github.com/hsutter/cppfront.git .cache/repos/cppfront --quiet
+)
+
+call "%vs_install_dir%\Common7\Tools\vsdevcmd.bat" /no_logo
+
+if not exist "%modules_dir%\std.ifc" (
+	echo Compiling std module...
+	pushd %modules_dir%
+	cl /std:c++latest /EHsc /nologo /W4 /MTd /c "%vs_tools_dir%\modules\std.ixx"
+	popd
+)
+
+if not exist "%modules_dir%\std.compat.ifc" (
+	echo Compiling std.compat module...
+	pushd %modules_dir%
+	cl /std:c++latest /EHsc /nologo /W4 /MTd /c "%vs_tools_dir%\modules\std.compat.ixx"
+	popd
+)
+
+if not exist %cppfront% (
+	pushd .cache\repos\cppfront\source
+	echo Compiling cppfront...
+	cl /nologo /std:c++latest /EHsc cppfront.cpp
+	xcopy /y /q cppfront.exe %cppfront%
+	popd
+)
+
+%cppfront% src/main.cpp2 -pure -import-std -add-source-info -format-colon-errors
+
+if %ERRORLEVEL% neq 0 exit %ERRORLEVEL%
+
+cl /nologo src/main.cpp ^
+  /diagnostics:caret /permissive- ^
+  /reference "%modules_dir%\std.ifc" "%modules_dir%\std.obj" ^
+  /reference "%modules_dir%\std.compat.ifc" "%modules_dir%\std.compat.obj" ^
+  /std:c++latest /W4 /MTd /EHsc ^
+  -I"%cppfront_include_dir%" ^
+  /Fe"%cpp2b_dist%"
+
+if %ERRORLEVEL% neq 0 exit %ERRORLEVEL%
+
+echo %cpp2b_dist%.exe

clean.cmd

@@ -0,0 +1,3 @@
+@echo off
+
+@rd /S /Q ".cache"

cpp2b.toml

@@ -0,0 +1,7 @@
+@echo off
+
+set cpp2b_dist=%~dp0dist\debug\cpp2b
+
+call %~dp0build.cmd
+
+xcopy /y /q %cpp2b_dist%.exe %USERPROFILE%\.local\bin\

install.cmd

@@ -0,0 +1,58 @@
+fs: namespace == std::filesystem;
+
+ensure_dir: (dir: fs::path) = {
+	status := fs::status(dir);
+
+	if status.type() == fs::file_type::not_found {
+		fs::create_directories(dir);
+	}
+}
+
+
+find_closest_file: (filename) find_closest_file(filename, fs::current_path());
+find_closest_file: (filename, base: fs::path) -> std::optional<fs::path> = {
+	if fs::exists(base / filename) {
+		return base / filename;
+	}
+
+	if !base.has_parent_path() || base.parent_path() == base {
+		return std::nullopt;
+	}
+
+	return find_closest_file(filename, base.parent_path());
+}
+
+expect: <T>(move opt: std::optional<T>, message) -> T = {
+	if !opt {
+		std::println("ERROR: {}", message);
+		std::abort();
+	}
+
+	return opt*;
+}
+
+expect: <T>(move v: std::variant, message) -> T = {
+	if !std::holds_alternative<T>(v) {
+		panic("ERROR: {}", message);
+	}
+
+	return std::get<T>(v);
+}
+
+main: (args) -> int = {
+	cpp2b_config_file := find_closest_file("cpp2b.toml").expect("Cannot find cpp2b config file. Are you sure you're running cpp2b in a cpp2b project?");
+
+	std::println("Found cpp2b config file: {}", cpp2b_config_file.string());
+
+	fs::current_path(cpp2b_config_file.parent_path());
+
+	ensure_dir(".cache/modules");
+	ensure_dir(".cache/repos");
+	ensure_dir(".cache/tools");
+
+	for args do (arg) {
+		std::println("arg={}", arg);
+	}
+
+	return 0;
+}